Sturzi's Arduino-Bastel-Projekt #1 - Es werde Licht

Zitat von egos

Das Programm für 2 LEDs (Post #52) läuft bei mir einwandfrei

Weiterhin viel Erfolg!

Peter, deine LED-Leisten gefallen mir.

Verwendung einer Photo-Diode, um die Blinkerei bei hellem Licht auszuschalten

Ich habe bei meiner Schaltung die Verstellung der Intervall-Dauer mit dem Potientiometer wieder herausgenommen, um das Programm für die weiteren Schritte so kompakt wir möglich zu halten. Der praktische Sinn, die Intervalle verstellen zu können, ist eher klein, weil die Intervalle ja sehr gut mit den vier Konstanten (Zeilen 1 bis 4) eingestellt werden können. Ihr könnte es bei eurer Version aber auch gern drin lassen.

Ich starte also für diesen neuen Schritt mit folgender Version:

const long MIN_OFF_TIME = 5000;
const long MAX_OFF_TIME = 90000;
const long MIN_ON_TIME = 5000;
const long MAX_ON_TIME = 90000;

const byte pinsUsedForLEDs[] = {2, 3, 4, 5, 6, 7, 8, 9, 10, 11};
const byte numOfLEDsUsed = sizeof(pinsUsedForLEDs);

long millisOnLastStatusChange[numOfLEDsUsed];
long millisToWait[numOfLEDsUsed];

void setup() {
  for (int i = 0; i < numOfLEDsUsed; i++) {
    pinMode(pinsUsedForLEDs[i], OUTPUT);
    changeStatus(i);
  }
}

void loop() {
  long currentMillis = millis();
  for (int i = 0; i < numOfLEDsUsed; i++) {
    if ((currentMillis - millisOnLastStatusChange[i]) >= millisToWait[i]) {
      changeStatus(i);
    }
  }
}

void changeStatus(int idx) {
  byte pin = pinsUsedForLEDs[idx];
  bool newStatus = ! digitalRead(pin); 
  digitalWrite(pin, newStatus);
  if (newStatus == LOW) {
    millisToWait[idx] = random(MIN_OFF_TIME, MAX_OFF_TIME);
  } else {
    millisToWait[idx] = random(MIN_ON_TIME, MAX_ON_TIME);
  }
  millisOnLastStatusChange[idx] = millis();
}

Bei diesem neuen Schritt geht es nun darum, den Lichtsensor (oder Photo-Diode oder Ambient Light Sensor) aus dem Starter-Kit einzusetzen.

Der Lichtsensor wird an einen analogen Eingang angeschlossen. Die Spannung variiert mit der Helligkeit beim Lichtsensor. Je heller es ist, desto kleiner wird die Spannung.

Mit Hilfe einer Konstanten werden wir einen Threshold (Schwellwert) einstellen. Das Programm wird so modifiziert, dass die Dioden nur dann leuchten, bzw. blinken, wenn das Licht im Raum unter diesen Schwellwert fällt.

Man schalte die Anode (das längere Ende) der Photodiode über einen 10 kΩ Widerstand an 5V und zusätzlich an einen analogen Eingang des Arduino (ich habe hier A0 gewählt). Die Kathode (das kürzere Ende) schalte man an Ground.

Hinweis: Im Projektbuch des Arduino Starter-Kit wird von einem Photo-Widerstand (der wäre nicht polaritäts-abhängig) gesprochen. Es liegen hingegen Photo-Dioden bei, die polaritäts-abghängig sind. Mindestens bei meinem Starter Kit ist das so.

Das neue Programm, welches die Photo-Diode berücksichtigt, sieht bei mir so aus:

const long MIN_OFF_TIME = 500;
const long MAX_OFF_TIME = 9000;
const long MIN_ON_TIME = 500;
const long MAX_ON_TIME = 9000;

const int LIGHT_THRESHOLD = 860;

const byte pinsUsedForLEDs[] = {2, 3, 4, 5, 6, 7, 8, 9, 10, 11};
const byte numOfLEDsUsed = sizeof(pinsUsedForLEDs);

const byte ANALOG_INPUT_FOR_PHOTO_LED = A0;

long millisOnLastStatusChange[numOfLEDsUsed];
long millisToWait[numOfLEDsUsed];

void setup() {
  Serial.begin(9600);
  for (int i = 0; i < numOfLEDsUsed; i++) {
    pinMode(pinsUsedForLEDs[i], OUTPUT);
    changeStatus(i);
  }
}

void loop() {
  long currentMillis = millis();
  for (int i = 0; i < numOfLEDsUsed; i++) {
    if ((currentMillis - millisOnLastStatusChange[i]) >= millisToWait[i]) {
      changeStatus(i);
    }
  }
}

void changeStatus(int idx) {
  byte pin = pinsUsedForLEDs[idx];
  bool newStatus = ! digitalRead(pin);

  int analogValue = analogRead(ANALOG_INPUT_FOR_PHOTO_LED);
  Serial.println(analogValue);
  if (analogValue < LIGHT_THRESHOLD) {
    newStatus = LOW;
  }
  
  digitalWrite(pin, newStatus);
  if (newStatus == LOW || analogValue < LIGHT_THRESHOLD) {
    millisToWait[idx] = random(MIN_OFF_TIME, MAX_OFF_TIME);
  } else {
    millisToWait[idx] = random(MIN_ON_TIME, MAX_ON_TIME);
  }
  millisOnLastStatusChange[idx] = millis();
}

Was neu ist:

Zeilen 1 bis 4: Ich habe provisorisch die Blink-Intervalle etwas heruntergesetzt, dass man nicht zu lange warten muss, bis wieder etwas leuchtet oder ablöscht.

Zeile 6: Hier ist ein Grenzwert definiert. Wenn der Eingangs-Wert unter diesem liegt, ist es so hell, dass die LEDs ausgeschaltet werden können. Dieser Wert kann je nach Exemplar der Photo-Diode oder der Lichtverhältnisse in eurem Raum ganz anders liegen. Er ist aber sicher im Bereich 0 ... 1023.

Zeile 11: Hier muss man den Analogen Eingang, den man gewählt hat, angeben (bei mir A0).

Zeile 17: Serial.begin(), damit wir den Wert des analogen Eingangs auf dem Serial Monitor anzeigen können. Das kann später wieder entfernt werden.

Zeile 37: Hier wird der analoge Eingang eingelesen und in der Variablen analogValue gespeichert.

Zeile 38: Damit man auch sieht, was man analog eingelesen hat, wird dieser Wert auf den Serial Monitor geschickt. Das hilft zum Einstellen des LIGHT_THRESHOLD. Das kann später wieder entfernt werden.

Zeilen 39 bis 41: Wenn es im Raum hell genug ist (also wenn der eingelesene Analog-Wert kleiner ist als der Threshold), wir der newStatus auf LOW gesetzt (unabhängig davon, wie er der Zeile 35 vorbereitet wurde). So wird sichergestellt, dass die LEDs ablöschen.

Jeder muss nun individuell seinen LIGHT_THRESHOLD so einstellen, dass es bei ihm funktioniert.